Note: ALL OSOYOO Products for Arduino are Third Party Board which is fully compatitable with Arduino

Authorized Online Retailers:

Content

1. Introduction
2. Preparations
   • Hardware
   • Software
3. About the IR
   • What is IR?
   • Modulation
   • Technical Details of VS1838B IR Receiver
   • The pinout for VS1838B IR Receiver:
   • About the IR control
   • IR-REMOTE LIBRARY
4. Examples
   • Read codes from IR Remote
     • Connection
     • Code Program
     • Running Result
   • IR Remote Test
     • Code Program
     • Running Result
   • IR Control LED
     • Connection
     • Code Program
     • Running Result

Introduction

IR, or infrared, communication is a common, inexpensive, and easy to use wireless communication technology. IR light is very similar to visible light, except that it has a slightlty longer wavelength. This means IR is undetectable to the human eye – perfect for wireless communication. For example, when you hit a button on your TV remote, an IR LED repeatedly turns on and off, 38,000 time a second, to transmit information (like volume or channel control) to an IR photo sensor on your TV.

This tutorial will first explain the inner workings of common IR communication protocols. Then we will go over three examples that will allow you to transmit and receive IR data using an Arduin. In the first example, we will read incoming IR data from a common remote control using the 1838B IR photo sensor. The next example will show you how to test the IR remote and print the corrsponding button name on the Serial Monitor. The third example will show you how to transmit data from an IR receiver to control a common appliance, such as turn on an LED.

Preparations

Hardware

• Osoyoo basic Board (Fully compatible with Arduino UNO rev.3) x 1
• Infrared Receiver x 1
• Remote Controller x 1
• LED x 1
• 200 ohm Resistor x 1
• Breadboard x 1
• Jumpers
• USB Cable x 1
• PC x 1

Software

• Arduino IDE (version 1.6.4+)
• IRremote.h

About the IR

What is IR?

Infra-Red light is actually normal light with a particular colour. We humans can’t see this colour because its wave length of about 950nm is below the visible spectrum. That’s one of the reasons why IR is chosen for remote control purposes, we want to use it but we’re not interested in seeing it. Another reason is because IR LEDs are quite easy to make, and therefore can be very cheap, thus making it ideal for us hobbyists to use IR control for our own projects.

We need to konw there are many more sources of Infra-Red light. The sun is the brightest source of all, but there are many others, like: light bulbs, candles, central heating system, and even our body radiates Infra-Red light.

A common modulation scheme for IR communication is something called 38kHz modulation. There are very few natural sources that have the regularity of a 38kHz signal, so an IR transmitter sending data at that frequency would stand out among the ambient IR. 38kHz modulated IR data is the most common, but other frequencies can be used.

When you hit a key on your remote, the transmitting IR LED will blink very quickly for a fraction of a second, transmitting encoded data to your appliance.

If you were to hook an oscilloscope up to your TV remote’s IR LED, you would see a signal similar to the one above. This modulated signal is exactly what the receiving system sees. However, the point of the receiving device is to demodulate the signal and output a binary waveform that can be read by a microcontroller. When you read the OUT pin of the VS1838B with the wave from above, you will see something like the second.

Modulation

As everything that radiates heat, also radiates Infra-Red light. Therefore we have to take some precautions to guarantee that our IR message gets across to the receiver without errors.Modulation of the signal on a carrier frequency is the answer to make our signal stand out above the noise. With modulation we make the IR light source blink in a particular frequency. The IR receiver will be tuned to that frequency, so it can ignore everything else.

In the picture below you can see a modulated signal driving the IR LED of the transmitter on the left side. The detected signal is coming out of the receiver at the other side.

(Thanks to SBProjects.com for the gif and excellent IR resource!)

Technical Details of  VS1838B IR Receiver

• Model Number : VS1838B;
• Working Voltage :2.7V to 5.5V
• Reception Distance : 18M;
• Reception Angle : ± 45 Degree;
• Low Level Voltage : 0.4V
• High Level Voltage : 4.5V;
• Body Size : 7 x 7 x 5mm / 0.27″ x 0.27″ x 0.2″(L*W*T);
• Pin Length : 22.5mm / 0.88″
• Pitch : 2mm / 0.08″;

The pinout for VS1838B IR Receiver:

About the IR control

Infrared remotes are still the cheapest way to wirelessly control a device. We have designed the remote to be small, very simple, and low-cost.There are many different IR remote controls. all of these may have different encoding methods and number of physical buttons, and different codes received when a button is pressed.

IR-REMOTE LIBRARY:

Note: The following library must be installed in your installation for this to work!

CLICK HERE – IR REMOTE CONTROL: ARgithub.com/shirriff/IRremoteDUINO LIBRARY

NOTE!! If you have a late version of Arduin with a library IRRobotRemote, it may conflict and you may have to remove that library.Make sure to delete Arduin(root)/libraries/RobotIRremote. Where Arduin(root) refers to the install directory of Arduino. The library RobotIRremote has similar definitions to IRremote and causes errors.

Examples

Read codes from IR Remote

This example will show you how to read IR remote codes from any IR remote using the VS1838B IR receiver and an board for Arduino. Once you can receive codes from individual button presses, your remote control and Arduin become a general purpose, short range, communication interface!

The first thing you need to do is make sure the IR library has been installed, Instructions on how to install an Arduin library can be found here.

Connection

Build the circuit as below:

Code Program

After above operations are completed, connect the board to your computer using the USB cable. The green power LED (labelled PWR) should go on.Open the Arduino IDE and choose corresponding board type and port type for you project. Then load up the following sketch onto your board.

#include <IRremote.h>  // use the IRRemote.h
const int irReceiverPin = 2;  //the SIG of receiver module attach to pin2
IRrecv irrecv(irReceiverPin); //Creates a variable of type IRrecv
decode_results results;    // define resultsas 

void setup()
{
  Serial.begin(9600);    //initialize serial,baudrate is 9600
  irrecv.enableIRIn();   // enable ir receiver module
}

void loop() 
{
  if (irrecv.decode(&results)) //if the ir receiver module receiver data
  {  
    Serial.print("irCode: ");    //print "irCode: "        
    Serial.print(results.value, HEX); //print the value in hexdecimal 
    Serial.print(",  bits: ");  //print" , bits: "         
    Serial.println(results.bits); //print the bits
    irrecv.resume();    // Receive the next value 
  }  
  delay(600); //delay 600ms
}

When specific buttons are pressed, you can use the incoming values to do something else in your code, for example turn on and off a motor or LED.

The results from each button press can be found by calling the value() method:

results.value

You can print the values to the Serial Monitor window:

Serial.println(results.value, HEX); //prints the hex value a a button press

Running Result

The sketch will automatically decode the type of remote you are using and identify which button on your remote is pressed. Open the Serial Monitor in the Arduino IDE at 9600 bps and hit different buttons on your remote.

The Serial Monitor displaying random button presses on my remote. Different buttons show different codes:

If you use the sketch above and count the 21 buttons from left to right and top to bottom, the codes received are these: (NOTE: Receiving “FFFFFFFF” means “repeat” if you hold the button down.)

IR Remote Test

When specific buttons are pressed, you can use the incoming values to do something else in your code, for example turn on and off a motor or LED.

This example is to test the IR receiver, we modify the last sketch, when specific buttons are pressed, we will use the incoming values to print the corrseponding buttons’ name of the IR control. The hardware connection is same as above example, before uplod the code, make sure you have installed the IRremote library!

Code Program

After above operations are completed, connect the board to your computer using the USB cable. The green power LED (labelled PWR) should go on.Open the Arduino IDE and choose corresponding board type and port type for you project. Then load up the following sketch onto your board.

#include "IRremote.h"
/*-----( Declare Constants )-----*/
int receiver = 2; // pin 1 of IR receiver to Arduin digital pin 2
/*-----( Declare objects )-----*/
IRrecv irrecv(receiver);           // create instance of 'irrecv'
decode_results results;            // create instance of 'decode_results'
/*-----( Declare Variables )-----*/

void setup()   /*----( SETUP: RUNS ONCE )----*/
{
  Serial.begin(9600);
  Serial.println("IR Receiver Raw Data + Button Decode Test");
  irrecv.enableIRIn(); // Start the receiver
}/*--(end setup )---*/

void loop()   /*----( LOOP: RUNS CONSTANTLY )----*/
{
  if (irrecv.decode(&results)) // have we received an IR signal?
  {
//    Serial.println(results.value, HEX);  UN Comment to see raw values
    translateIR(); 
    irrecv.resume(); // receive the next value
  }  
}/* --(end main loop )-- */

/*-----( Declare User-written Functions )-----*/
void translateIR() // takes action based on IR code received
{
  switch(results.value)
  {
  case 0xFFA25D:  
    Serial.println(" CH-            "); 
    break;
  case 0xFF629D:  
    Serial.println(" CH             "); 
    break;
  case 0xFFE21D:  
    Serial.println(" CH+            "); 
    break;
  case 0xFF22DD:  
    Serial.println(" PREV           "); 
    break;
  case 0xFF02FD:  
    Serial.println(" NEXT           "); 
    break;
  case 0xFFC23D:  
    Serial.println(" PLAY/PAUSE     "); 
    break;
  case 0xFFE01F:  
    Serial.println(" VOL-           "); 
    break;
  case 0xFFA857:  
    Serial.println(" VOL+           "); 
    break;
  case 0xFF906F:  
    Serial.println(" EQ             "); 
    break;
  case 0xFF6897:  
    Serial.println(" 0              "); 
    break;
  case 0xFF9867:  
    Serial.println(" 100+           "); 
    break;
  case 0xFFB04F:  
    Serial.println(" 200+           "); 
    break;
  case 0xFF30CF:  
    Serial.println(" 1              "); 
    break;
  case 0xFF18E7:  
    Serial.println(" 2              "); 
    break;
  case 0xFF7A85:  
    Serial.println(" 3              "); 
    break;
  case 0xFF10EF:  
    Serial.println(" 4              "); 
    break;
  case 0xFF38C7:  
    Serial.println(" 5              "); 
    break;
  case 0xFF5AA5:  
    Serial.println(" 6              "); 
    break;
  case 0xFF42BD:  
    Serial.println(" 7              "); 
    break;
  case 0xFF4AB5:  
    Serial.println(" 8              "); 
    break;
  case 0xFF52AD:  
    Serial.println(" 9              "); 
    break;
  default: 
    Serial.println(" other button   ");
  }
  delay(500);
} //END translateIR

Running Result

A few seconds after the upload finishes,  hit different buttons on your remote.

open the serial port in the Arduino IDE at 9600 bps, you should see the software below displays the button that was pressed:

Note: The Serial Monitor printing “other button” means the incoming values are not corresponding to your IR remote codes, it may appear if you hold the button down or there are other disturbances.

IR Control LED

Control a certain key (for example, Power key) via a remote controller by programming. When you press the key, infrared rays will be emitted from the remote control and received by the infrared receiver, and the LED on the Osoyoo basic board will light up. Connect an LED to pin 3 on the Osoyoo basic board so that you can see remotely whether the Power  key is pressed down.

Connection

Build the circuit as below:

Code Program

After above operations are completed, connect the board to your computer using the USB cable. The green power LED (labelled PWR) should go on. Load up the following sketch onto your board.

#include <IRremote.h>
const int irReceiverPin =2; //the SIG of receiver module attach to pin2 
const int ledPin = 3;//pin 3 connect to an led
IRrecv irrecv(irReceiverPin); //Creates a variable of type IRrecv
decode_results results;
void setup()
{
  pinMode(ledPin,OUTPUT);//set ledpin as OUTPUT
  Serial.begin(9600);//initialize serial 
  irrecv.enableIRIn(); //enable ir receiver module 
}
void loop() 
{
  if (irrecv.decode(&results)) //if the ir receiver module receiver data
  { 
    Serial.print("irCode: "); //print"irCode: " 
    Serial.print(results.value, HEX); //print the value in hexdecimal 
    Serial.print(", bits: "); //print" , bits: " 
    Serial.println(results.bits); //print the bits
    irrecv.resume(); // Receive the next value 
  } 
  delay(600); //delay 600ms
  if(results.value == 0xFFA25D)//if receiver module receive 0xFFA25D
  {
    digitalWrite(ledPin,HIGH);//turn on the led
  }
  else
  {
    digitalWrite(ledPin,LOW);//turn off the led
  }
}

Running Result

A few seconds after the upload finishes, press the “CH-” button of a remote control, and both the LED attached and that connected to pin 3 on the Osoyoo basic board will light up. Then press any other key, and the LEDs will go out.